Como fazer backup e restaurar as configurações de visualização de pastas no Windows 10

No Windows, você pode alterar a visualização do modelo, a largura da coluna, agrupar por , classificar por e o layout do conteúdo da pasta da maneira que desejar.

Este tutorial mostrará como fazer backup e restaurar configurações de visualização de pastas, detalhes, largura e tamanho do painel de visualização, largura da janela de navegação, caixas de diálogo Abrir e Salvar como para qualquer conta no Windows 10 .

Veja como:

1. Baixe o arquivo Backup_and_Restore_Folder_View_Settings_Tool.bat .

Observação :

Este arquivo .bat aplicará apenas um backup e restauração à conta atual.

Abaixo está o conteúdo deste arquivo .bat para referência:

Código:

@ECHO OFF

Set "+=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders"
For /F "tokens=* " %%# in ('Reg Query "%+%" /V Desktop') Do (Set "#=%%#")
Set "#=%#:*REG_EXPAND_SZ    =%"
For /F "delims=" %%# in ('Echo "%#%"') Do (Set "#=%%#")
Set "[Desktop]=%#:~1,-1%"


title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice


:verify1
IF EXIST "%[Desktop]%\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice


:backup
mkdir "%[Desktop]%\Folder View Settings Backup"
REG EXPORT "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg" /y 
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg" /y
REG EXPORT "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%[Desktop]%\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice


:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\GlobalSettings\Sizer" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Modules\NavPane" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDOpen" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\CIDSave" /F
Reg Delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\ComDlg32" /F

REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_GlobalSettings_Sizer.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_Modules_NavPane.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDOpen.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_CIDSave.reg"
REG IMPORT "%[Desktop]%\Folder View Settings Backup\HKCU_SOFTWARE_Microsoft_Windows_CurrentVersion_Explorer_ComDlg32.reg"

cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

2. Salve o arquivo .bat na área de trabalho.

3. Desbloqueie arquivos .bat.

4. Execute o arquivo .bat.

5. Faça o que deseja em Ferramenta de configurações de exibição de pasta de backup e restauração .

Como fazer backup e restaurar o layout do menu Iniciar

CÓPIA DE SEGURANÇA:

Quando você cria um backup das configurações de visualização de pastas, a pasta Backup das configurações de visualização de pastas é salva na área de trabalho contendo arquivos .reg exportados do registro para suas configurações de visualização de pastas. Você pode salvar esta pasta onde desejar por segurança.

RESTAURAR:

Quando quiser restaurar um backup das configurações de visualização de pastas, primeiro você precisa ter uma pasta de backup das configurações de visualização de pastas com esse nome exato em sua área de trabalho para prosseguir com o processo de restauração.

Como fazer backup e restaurar as configurações de visualização de pastas no Windows 10

Faça backup e restaure as configurações de visualização de pastas no Windows 10

Espero que você tenha sucesso.

Deixar um comentário

Como remover o aviso de solicitação de direitos autorais no canto direito da tela do Windows 10

Você vê uma notificação de ativação do Windows 10 no canto direito da tela? Este artigo irá orientá-lo sobre como excluir o aviso de solicitação de direitos autorais no Windows 10.

Instruções do AZ sobre como instalar o Windows 10 build 14393.222

Recentemente, a Microsoft lançou a atualização cumulativa mais recente para usuários de PC com Windows 10, chamada Build 14393.222. Esta atualização lançada para o Windows 10 corrige principalmente bugs com base no feedback do usuário e melhora a experiência de desempenho do sistema operacional.

Proteja sua rede de computadores com host Bastion em apenas 3 etapas

Você tem computadores em sua rede local que precisam de acesso externo? Usar um host bastião como gatekeeper para sua rede pode ser uma boa solução.

3 maneiras de limpar rapidamente todos os logs de eventos no Windows 10

Às vezes, pode ser necessário excluir logs de eventos antigos de uma só vez. Neste guia, Quantrimang.com mostrará três maneiras de excluir rapidamente todos os logs de eventos no Visualizador de Eventos do Windows 10.

Como criar uma tecla do Windows se o seu teclado não estiver disponível

Se você preferir usar um teclado clássico antigo, como o IBM Modelo M, que não inclui uma tecla física do Windows, existe um método fácil de adicionar mais, pegando emprestada uma tecla que você não usa com frequência.

Como criar modo de fundo transparente no Windows 10

WindowTop é uma ferramenta que tem a capacidade de escurecer todas as janelas de aplicativos e programas em execução em computadores com Windows 10. Ou você pode usar uma interface de fundo escuro no Windows.

Métodos de IP falso ajudam você a acessar anonimamente

Em muitos artigos anteriores, mencionamos que permanecer anônimo online é extremamente importante. Informações privadas vazam todos os anos, tornando a segurança online cada vez mais necessária. Essa também é a razão pela qual devemos usar endereços IP virtuais. Abaixo, aprenderemos sobre métodos para criar IPs falsos!

Como desativar a barra de idiomas na barra de tarefas do Windows 8

A barra de idiomas do Windows 8 é uma barra de ferramentas de idiomas em miniatura projetada para ser exibida automaticamente na tela da área de trabalho. No entanto, muitas pessoas desejam ocultar esta barra de idiomas na barra de tarefas.

Dicas para otimizar a velocidade da conexão com a Internet da Linksys

Maximizar a velocidade da Internet é essencial para otimizar sua conexão de rede. Você pode ter uma ótima experiência de entretenimento e trabalho usando computadores, TVs com Internet, consoles de jogos, etc.

Como configurar WEP, WPA, WPA2 para roteador Linksys

A conectividade sem fio é uma necessidade hoje e por isso a segurança sem fio é essencial para garantir a segurança da sua rede interna.