Makrolarınızı Hızlandırmanın 10 Yolu

Aşırı Referanstan Kaçının

Bir nesnenin yöntemini veya özelliğini çağırırken, OLE bileşeninin IDispatch arabiriminden geçmesi gerekir. Bu OLE bileşenlerine yapılan çağrılar zaman alır, dolayısıyla OLE bileşenlerine yapılan başvuruların sayısını azaltmak makro kodun hızını artırabilir.

Nesne özelliklerinin veya yöntemlerinin çağrılması için  genellikle Object.Method'un temsil yöntemi  , yani "." kullanılır. Sembol, özellikleri ve yöntemleri çağırmak için kullanılır.

Bu nedenle yöntem veya özellik çağrılarının sayısı "." sembollerinin sayısına göre değerlendirilebilir. "." ne kadar azsa sembolü, kod ne kadar hızlı çalışırsa.

Örneğin aşağıdaki ifadede 3 sembol "." bulunmaktadır.

ThisWorkbook.Sheet1.Range("A1").Value = 100

Aşağıdaki ifadede yalnızca bir "." simgesi vardır.

Activewindow.Top = 100

İşte "." sembollerinin sayısını azaltmak için bazı püf noktaları. daha hızlı koşmak için.

İlk olarak, aynı nesneye tekrar tekrar başvurmanız gerektiğinde, çağrı sayısını azaltmak için nesneyi bir değişkene ayarlayabilirsiniz. Örneğin aşağıdaki kod, satır başına iki çağrı gerektirir.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

Sheets("Sheet1") nesnesine tekrar tekrar başvurulması gerektiğinden  , önce sht  değişkenine ayarlanabilir   , böylece her kodun yalnızca bir kez çağrılması yeterli olur.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

İkincisi, geçici bir sht değişkeni bildirmek istemiyorsanız,  daha önce bahsedilen With  ifadesini de kullanabilirsiniz. Aşağıdaki örnekte gösterildiği gibi:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

Üçüncüsü,  çok sayıda döngü olduğunda özellikleri ve yöntemleri döngünün dışında tutmaya çalışın.  Aynı nesnenin özellik değerini bir döngüde yeniden kullanırken, önce özellik değerini döngünün dışındaki belirli bir değişkene atayabilir ve daha sonra daha hızlı hız elde edebilecek şekilde döngüdeki değişkeni kullanabilirsiniz. Aşağıdaki örnekte gösterildiği gibi:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

Bu örnekteki her döngü, Cells(1,2) hücresinin Value özelliğini alır. Döngü başlamadan önce Cells(1.2)'in Value özelliğini bir değişkene atarsanız daha hızlı bir çalışma elde edersiniz. Aşağıdaki örnekte gösterildiği gibi:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

Yukarıdaki kod  her döngüde ThisWorkbook.Sheets("Sheet1")  öğesini çağırır.  Çağrıyı döngünün dışındaki ThisWorkbook.Sheets("Sheet1")  öğesine taşımak için  With deyimini kullanarak bunu daha hızlı yapabilirsiniz  . Aşağıdaki örnekte gösterildiği gibi:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

Varyant Türlerini Kullanmaktan Kaçının

Yeni başlayanlar genellikle Variant türü değişkenleri kullanmayı tercih ederler; bu, daha az karmaşık olma avantajına sahiptir çünkü veriler Tamsayı veya Uzun veri türleri için çok büyükse, herhangi bir veri türü bellek taşması sorunu olmadan kullanılabilir. Ancak Varienmt türü veriler, belirtilen diğer türlere göre daha fazla ekstra bellek alanı gerektirir (Tamsayı verileri için 2 bayt, Uzun veriler için 4 bayt ve Variant verileri için 16 bayt), VBA, Variant türü verileri işlemek için diğer belirtilen türlere göre daha fazla zaman gerektirir. veri. Aşağıdaki örnekte gösterildiği gibi.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

Yukarıdaki kodda, 8'den 13'e kadar olan satırlar, Variant değişkenlerinde 1 milyon toplama, çıkarma, çarpma ve bölme işlemi gerçekleştirir ve 17'den 22'ye kadar olan satırlar, Tamsayı değişkenlerinde 1 milyon toplama, çıkarma, çarpma ve bölme işlemi yapar. Bilgisayarımda Variant değişkeninin işlemi yaklaşık  0,09375  saniye sürerken, Integer değişkeninin işlemi yaklaşık  0,03125  saniye sürdü. Sonuçlar bilgisayardan bilgisayara farklılık gösterebilir ancak  Variant değişkenleri Tamsayı değişkenlerinden önemli ölçüde daha yavaştır .

Bu nedenle,  belirtilen veri türünü açıkça kullanabileceğiniz durumlarda Variant değişkenlerini kullanmaktan kaçınmanız önerilir .