10 طرق لتسريع وحدات الماكرو الخاصة بك

تجنب المرجعية المفرطة

عند استدعاء أسلوب أو خاصية كائن ما، فإنه يحتاج إلى المرور عبر واجهة IDispatch الخاصة بمكون OLE. تستغرق الاستدعاءات إلى مكونات OLE هذه وقتًا، لذا فإن تقليل عدد المراجع إلى مكونات OLE يمكن أن يؤدي إلى تحسين سرعة تعليمات الماكرو البرمجية.

لاستدعاء خصائص الكائن أو الأساليب، يتم استخدام طريقة تمثيل  Object.Method  بشكل عام، أي "." يستخدم الرمز لاستدعاء الخصائص والأساليب.

لذلك، يمكن الحكم على عدد استدعاءات الأسلوب أو الخاصية وفقًا لعدد الرموز ".". كلما قل "." الرمز، كلما تم تشغيل الكود بشكل أسرع.

على سبيل المثال، تتضمن العبارة التالية 3 رموز ".".

ThisWorkbook.Sheet1.Range("A1").Value = 100

العبارة التالية لها رمز واحد فقط ".".

Activewindow.Top = 100

فيما يلي بعض الحيل لتقليل عدد الرموز "." لتشغيل أسرع.

أولاً، عندما تحتاج إلى الإشارة إلى نفس الكائن بشكل متكرر، يمكنك تعيين الكائن إلى متغير لتقليل عدد الاستدعاءات. على سبيل المثال، يتطلب التعليمة البرمجية التالية مكالمتين لكل سطر.

ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = 100
ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = 200
ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = 300

نظرًا لأن  كائن Sheets("Sheet1")  يحتاج إلى الرجوع إليه بشكل متكرر، فيمكن تعيينه على متغير  sht  أولاً، بحيث يجب استدعاء كل رمز مرة واحدة فقط.

Set sht = ThisWorkbook.Sheets("Sheet1")
sht.Cells(1, 1) = 100
sht.Cells(2, 1) = 200
sht.Cells(3, 1) = 300

ثانيًا، إذا كنت لا تريد الإعلان عن متغير مؤقت sht، فيمكنك أيضًا استخدام عبارة  With  المذكورة سابقًا. كما هو موضح في المثال التالي:

With ThisWorkbook.Sheets("Sheet1")
    .Cells(1, 1) = 100
    .Cells(2, 1) = 200
    .Cells(3, 1) = 300
End With

ثالثًا،  عندما يكون هناك الكثير من الحلقات، حاول الاحتفاظ بالخصائص والأساليب خارج الحلقة.  عند إعادة استخدام قيمة خاصية لنفس الكائن في حلقة، يمكنك أولاً تعيين قيمة الخاصية لمتغير محدد خارج الحلقة، ثم استخدام المتغير الموجود في الحلقة، والذي يمكن أن يحقق سرعة أكبر. كما هو موضح في المثال التالي:

For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = Cells(1, 2).Value
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = Cells(1, 2).Value
Next i

تحصل كل حلقة في هذا المثال على خاصية القيمة للخلية Cells(1,2). إذا قمت بتعيين خاصية قيمة الخلايا (1.2) لمتغير قبل بدء الحلقة، فسوف تحصل على تشغيل أسرع. كما هو موضح في المثال التالي:

tmp = Cells(1, 2).Value
For i = 1 To 1000
    ThisWorkbook.Sheets("Sheet1").Cells(1, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(2, 1) = tmp
    ThisWorkbook.Sheets("Sheet1").Cells(3, 1) = tmp
Next i

يستدعي التعليمة البرمجية أعلاه  ThisWorkbook.Sheets("Sheet1")  في كل مرة يتم تكرارها. يمكنك القيام بذلك بشكل أسرع باستخدام  عبارة With  لنقل الاستدعاء إلى  ThisWorkbook.Sheets("Sheet1")  خارج الحلقة. كما هو موضح في المثال التالي:

tmp = Cells(1, 2).Value
With ThisWorkbook.Sheets("Sheet1")
    For i = 1 To 1000
        .Cells(1, 1) = tmp
        .Cells(2, 1) = tmp
        .Cells(3, 1) = tmp
    Next i
End With

تجنب استخدام أنواع المتغيرات

يفضل المبتدئون عادةً استخدام متغيرات النوع المتغير، والتي تتميز بكونها أقل تعقيدًا لأنه يمكن استخدام أي نوع من البيانات دون مشكلة تجاوز سعة الذاكرة إذا كانت البيانات كبيرة جدًا بالنسبة لأنواع البيانات الصحيحة أو الطويلة. ومع ذلك، تتطلب بيانات نوع Varienmt مساحة ذاكرة إضافية أكبر من الأنواع المحددة الأخرى (2 بايت للبيانات الصحيحة، و4 بايت للبيانات الطويلة، و16 بايت للبيانات المتغيرة)، ويتطلب VBA وقتًا أطول لمعالجة بيانات النوع المتغير مقارنة بالأنواع المحددة الأخرى البيانات. كما يظهر المثال التالي.

Sub VariantTest()
    Dim i As Long
    Dim ix As Integer, iy As Integer, iz As Integer
    Dim vx As Variant, vy As Variant, vz As Variant
    Dim tm As Date
    vx = 100: vy = 50
    tm = Timer
    For i = 1 To 1000000
        vz = vx * vy
        vz = vx + vy
        vz = vx - vy
        vz = vx / vy
    Next i
    Debug.Print "Variant types take " & Format((Timer - tm), "0.00000") & " seconds"
    ix = 100: iy = 50
    tm = Timer
    For i = 1 To 1000000
        iz = ix * iy
        iz = ix + iy
        iz = ix - iy
        iz = ix / iy
    Next i
    Debug.Print "Integer types take " & Format((Timer - tm), "0.00000") & " seconds"
End Sub

في الكود أعلاه، تقوم الأسطر من 8 إلى 13 بمليون عملية جمع وطرح وضرب وقسمة للمتغيرات المتغيرة، بينما تقوم الأسطر من 17 إلى 22 بمليون عملية جمع وطرح وضرب وقسمة للمتغيرات الصحيحة. على جهاز الكمبيوتر الخاص بي، استغرق تشغيل المتغير Variant حوالي  0.09375  ثانية، بينما استغرق تشغيل المتغير Integer حوالي  0.03125  ثانية. قد تختلف النتائج من كمبيوتر إلى آخر، لكن  المتغيرات المتغيرة تكون أبطأ بشكل ملحوظ من المتغيرات الصحيحة .

لهذا السبب،  يوصى بتجنب استخدام المتغيرات المتغيرة عندما يمكنك استخدام نوع البيانات المحدد بشكل صريح .